From news-rocq.inria.fr!jussieu.fr!math.ohio-state.edu!howland.reston.ans.net!newsfeed.internetmci.com!news.sesqui.net!rice!usenet Thu Dec 14 11:23:50 1995
Article: 3303 of rec.games.corewar
Path: news-rocq.inria.fr!jussieu.fr!math.ohio-state.edu!howland.reston.ans.net!newsfeed.internetmci.com!news.sesqui.net!rice!usenet
From: Kurt Franke <kfranke@rice.edu>
Newsgroups: rec.games.corewar
Subject: Persistence source
Date: 13 Dec 1995 22:35:34 GMT
Organization: Rice University, Houston, Texas
Lines: 95
Message-ID: <4ankfm$abr@larry.rice.edu>
NNTP-Posting-Host: lovett-2017.lovett.rice.edu
Mime-Version: 1.0
Content-Type: text/plain; charset=us-ascii
Content-Transfer-Encoding: 7bit
X-Mailer: Mozilla 1.22 (Windows; I; 16bit)

Here is the source for my program Persistence.  It is a 5 line
vampire/scanner together with an 8 line core clear.  The scanning step 
was chosen to beat rave.

Persistence is currently #6 on the 94 hill and holding steady.  Not 
exactly aging, but holding steady nonetheless.  ;-)  A few good stones 
and it is history, I think.  (Hoping people will start writing stones to 
save my replicator, Hector)

(I commented the places where I scan or bomb with ;; hit or ;; check)

Also, does anyone know a way to stun the bombers in die hard or impfinity 
very quickly?  please mail me.

---8<---

;redcode-94
;assert CORESIZE == 8000
;author Kurt Franke
;name Persistence

;strategy vamp/scan -> core clear
;strategy  (this version does better against imp-types)

for     0
        (I think this is the same as I sent in to pizza -- 
         but I might have changed the core clear a little.)

        This is a vampire/scanner along the same lines as myvamp.
        I bomb every 16th location with an instruction to jump into
        the pit.  The pit clears core forward from by warrior with
        3-point-imp-killing instructions, eventually killing itself.
        In between every bombed location, I scan to see if it is not
        zero and drop a dat bomb if it isn't.  After ten finds I go to
        the core clear part.
rof

step    equ     48

hell    spl     0, <-300
hell2   spl     0, <-200
hell3   spl     -1, <-100
        spl     -1, <-60
mbomb   mov     5, >1
        jmp     -1, cend+10
        dat     0,0                             ;; hit

        for     7
          dat   <2667, <2667*2
        rof

        for     41                              ;; check
          dat   0,0
        rof                                     ;; hit

        dat     0,0

loop    add.f   $incr, $jbomb                   ;; vamp/scan loop
        mov     $jbomb, @jbomb
        jmz.f   loop, *jbomb
        mov     $dbomb, *jbomb
ret     djn     loop, #10                       ;; start clear after 10

ptr     jmp     $sbomb2, $cend+6
dbomb   dat     #sbomb-ptr, }cend+6-ptr         ;; check
sbomb   spl     #dbomb-ptr, #cend+1-ptr
sbomb2  spl     #sbomb-ptr, #cend+6-ptr
clear   mov     *ptr, >ptr                      ;; 3/4 c core clear
        mov     *ptr, >ptr
        mov     *ptr, >ptr
cend    djn     -3, <loop-100
        dat     0,0
        dat     0,0                             ;; hit

        for     8
          dat   0,0
        rof                                     ;; check

        dat     0,0
        dat     0,0
        dat     0,0
        dat     0,0
incr    dat     step, -step
jbomb   jmp     hell-dbomb+8, dbomb-8
        dat     0,0
        dat     0,0                             ;; hit

        for     7
          dat   1,1                             ;; djn stream guard
        rof

        end     loop