From news-rocq.inria.fr!jussieu.fr!oleane!plug.news.pipex.net!pipex!tube.news.pipex.net!pipex!lade.news.pipex.net!pipex!tank.news.pipex.net!pipex!howland.reston.ans.net!ix.netcom.com!netcom.com!akemi Mon Mar  4 13:37:43 1996
Article: 4113 of rec.games.corewar
Newsgroups: rec.games.corewar
Path: news-rocq.inria.fr!jussieu.fr!oleane!plug.news.pipex.net!pipex!tube.news.pipex.net!pipex!lade.news.pipex.net!pipex!tank.news.pipex.net!pipex!howland.reston.ans.net!ix.netcom.com!netcom.com!akemi
From: akemi@netcom.com (David Boeren)
Subject: A bunch of my old warriors
Message-ID: <akemiDnKIuE.MMu@netcom.com>
Organization: NETCOM On-line Communication Services (408 261-4700 guest)
X-Newsreader: TIN [version 1.2 PL1]
Date: Fri, 1 Mar 1996 02:56:38 GMT
Lines: 188
Sender: akemi@netcom17.netcom.com

Just for fun, I have decided to post a bunch of my warriors.  All of these
were on the pro hill for a while except El Cheapo Scanner, which was never
even submitted to the pro hill.  It's my first real attempt at a scanner, so
forgive me if it isn't that good yet.  Maybe it will be helpful to the 
beginners though.  All of these are completely unmodified from the hill 
versions.  Mostly this is for Planar so he can get these for his archives...
Enjoy!


;redcode-94 verbose
;name Koolaid II: WoGG v2.2
;author David Boeren
;assert CORESIZE == 8000
;strategy Koolaid II: The Wrath of Goofy Grape v2.2
;strategy heavy stun bomber -> coreclear
;strategy     v0.1 New bombing engine with ideas from Tornado
;strategy     v2.0 Major rewrite for smaller code
;strategy     v2.1 Improved coreclear
;strategy     v2.2 Added boot & decoy

step    equ 184                     ; modulo 8 bombing
stepb   equ (step*2)
stepc   equ (step*3)
gate    equ ptr-7

        org boot
ptr     JMP.B      step,       #2
        DAT.F       #16,       #0
        SPL.B       #16,       #1
bomb1   SPL.B        #2,   #-step
bomb2   MOV.I        -1,      }-1   ; heavy stun bomb
loop    MOV.I     bomb2,    @targ
        MOV.I     bomb1,    <targ
        MOV.I       ptr,    *targ   ; ptr doubles as vamp
targ    MOV.I      step, @stepc+1
        ADD.F       inc,     targ
        DJN.B      loop,     #333   ; (8000/modulo)-1 bombs will be dropped
inc     SPL.B    #stepc, #stepc+1
clear   MOV.I      @ptr,     }ptr   ; Coreclear modified from Phosphorus
        DJN.F     clear,    <gate

boot    MOV.I   clear+1,     3198   ; fast boot away tail first
for 13
        MOV.I     {boot,    <boot
rof
        ADD.AB       #5,     boot   ; adjust so we split to "loop"
        SPL.B     @boot,       #1   ; split to main program
        MOV.I         0,     boot   ; obliterate boot pointer
for (MAXLENGTH-CURLINE) / 4
        DAT.F      loop,    clear   ; big decoy to confuse scanners
        DAT.F      targ,     boot   ; No two are alike!
        DAT.F      boot,     targ
        DAT.F     clear,     loop
rof
        END


;redcode-94 verbose
;name Paper Towel v0.4
;author David Boeren
;strategy Another paper test
;assert CORESIZE == 8000

pdest1  equ   3740
pdest2  equ  -1278                   ;pmars optimized
ptarg   equ    933                   ;pmars optimized

tdest1  equ   3488
tdest2  equ   1860
tdest3  equ   3740

        org start
start   SPL.B     towel,       #0

paper   SPL.B         1,       #0    ;\
        MOV.I        -1,       #0    ;-> generate 6 processes
        SPL.B         1,       #0    ;/

silk1   SPL.B        @0,  <pdest1
        MOV.I       }-1,      >-1
        MOV.I     pbomb,   }ptarg
        MOV.I    {silk1,   <silk2
silk2   JMP.B        @0,  >pdest2
pbomb   DAT.F     <2667,    <1143

for 50
        DAT.F        #0,       #0
rof


towel   SPL.B         1,       #0    ;\
        MOV.I        -1,       #0    ;-\ generate 10 processes
        MOV.I        -1,       #0    ;-/
        SPL.B         1,       #0    ;/

silka   SPL.B        @0,  }tdest1
        MOV.I       }-1,      >-1
        MOV.I     tbomb,     {123
silkb   SPL.B        @0,  }tdest2
        MOV.I       }-1,      >-1
        MOV.I     tbomb,    >1001
        MOV.I     tbomb,    }2042
        MOV.I    {silkb,   <silkc
silkc   JMP.B        @0,  >tdest3
tbomb   DAT.F     >2667,    >5334
        end


;redcode-94 verbose
;name Time Lapse v0.8
;author David Boeren
;assert CORESIZE == 8000
;strategy Bomber -> SPL/DAT coreclear
;strategy     v0.1 Fast bomber, does not use stun bombs
;strategy     v0.2 Added boot & decoy
;strategy     v0.8 Experiment with new bomb

step    equ 184
stepb   equ (step*2)
stepc   equ (step*3)
gate    equ loop-7

        org boot
ptr     DAT.F     #step,       #2
        DAT.F       #16,       #0
        SPL.B       #16,       #1
loop    MOV.I       ptr,    *targ   ; Tornado bombing
        MOV.I       ptr,    @targ
targ    MOV.I      step,   *stepb
        ADD.F       inc,     targ
        DJN.B      loop,     #333
inc     SPL.B    #stepc,   #stepc
clear   MOV.I      @ptr,     }ptr   ; Coreclear modified from Phosphorus
        DJN.F     clear,    <gate

boot    MOV.I   clear+1,     3198   ; fast boot away tail first
for 10
        MOV.I     {boot,    <boot
rof
        ADD.AB       #3,     boot   ; adjust so we split to "loop"
        SPL.B     @boot,       #1   ; split to main program
        MOV.I         0,     boot   ; obliterate boot pointer
        DAT.F      >100,     >101   ; die in a core-coloring way
for (MAXLENGTH-CURLINE) / 4
        DAT.F      loop,    clear   ; big decoy to confuse scanners
        DAT.F      targ,     boot   ; No two are alike!
        DAT.F      boot,     targ
        DAT.F     clear,     loop
rof
        END


;redcode-b
;name El Cheapo Scanner
;author David Boeren
;assert CORESIZE == 8000
;strategy JMZ scanner

step    equ 184                     ; modulo 8 bombing
gate    equ ptr-7

        org boot
ptr     DAT.F       #16,       #8
bomb2   MOV.I        -1,      >-1
        DAT.F       #12,       #0
kill    MOV.I     bomb2,    @targ 
targ    MOV.I     bomb1,       *0
scan    ADD.AB    #step,     targ
        JMZ.F      scan,    @targ
        JMN.B      kill,     targ
bomb1   SPL.B       #16,       #2
clear   MOV.I      @ptr,     }ptr    ; Coreclear modified from Phosphorus
        DJN.F     clear,    <gate

boot    MOV.I   clear+1,     3198    ; fast boot away tail first
for 10
        MOV.I     {boot,    <boot
rof
        ADD.AB       #5,     boot
        SPL.B     @boot,       #1    ; split to main program
        MOV.I         0,     boot    ; obliterate boot pointer

for (MAXLENGTH-CURLINE)
        DAT.F (scan*23),(targ*91)    ; big decoy to confuse scanners
rof
        END